Vodič za apsolutne početnike kroz
Skripte za Hamster
Skripte su objašnjenje, većim delom, kroz komentare unutar samih skripti...
Takodje sam napisao još neke zanimljive procedure sa objašnjenjem, ali su one ipak za "naprednije" korisnike...
Ostale skripte koje sam ja pisao za sebe se mogu naći ovde, i proizvod su prilagodjavanja Hamstera mojim potrebama...
Dakle, svako ih može koristiti i menjati prema svojim potrebama...
Osnovna skripta koja samo provera poštu, šalje poruke i skida news izgleda otprilike ovako:
###############################################################
# Osnovna skripta za proveru news-a, mail i sl.
# za jednog provajdera...
#
# Skriptu napisao: ANT-ilic (modifikovati po potrebi)
###############################################################
#!hs2
# Provera maila
HamFetchMail( "pop.hemo.net" )
# Slanje poruka
HamSendMail( "smtp.hemo.net" )
# Slanje poruka na news
HamNewsJobsPost( "news.hemo.net" )
# Priprema grupe za proveru newsa
hamnewsjobspull ("news.hemo.net")
# Pocetak skidanja poruka sa newsa
HamNewsJobsStart
# Kraj skripte
quit
Ovo je apsolutni potrebni minimum i nije potrebno neko dodatno objašnjenje...
Kada bi se pokrenula, iskočio bi prozorčić "Dial up connection", i po povezivanju skripta bi proverila sve navedeno gore...
U ovoj skripti ima dosta mesta za unapredjenje...
Obično je zamorno svakoga dana birati Connect, pa se otkačiti sa mreže kad se završi provera poruka na newsu i mail-u...
Zato se obično koristi malo izmenjena skripta:
###############################################################
# Povezivanje na provajdera u lite rezimu, provera poruka
# i prekidanje veze kada zavrsi.
#
# Skriptu napisao: ANT-ilic (modifikovati po potrebi)
###############################################################
#!hs2
Var ( $servers_to_post, $try , $save2)
$save2 = $scripts+"Sent-To_Delete.lst"
# Iskljucivanje lokalnih servera, radi predostroznosti, nije neophodno
# News
HamMessage ( 3, 0)
# POP3
HamMessage ( 4, 0)
# SMTP
HamMessage ( 5, 0)
# Ciscenje zadataka, u slucaju da je doslo do greske pri prethodnom povezivanju
HAmNewsJobsClear
Print ("Running: Hemo.Net@lite")
# Pokrece program za dodavanje headere, potpisa i uopste obradu poruka pre slanja
# Nije neophodno
Execute ( "korrnews\KorrNews.exe Mails News", "", 1, true )
Print ("Povezivanje... ...Skripta: Hemo.Net@lite")
# Brojac pokusaja
$try = 1
# Ime konekcije "Hemo.Net", korisnicko ime, lozinka
while( RasDial("Hemo.net" , "username@lite", "lozinka") != 0 )
if( $try >= 5 )
error( "Pozivanje neuspesno nakon pet pokusaja" )
endif
If (RasIsConnected)
Break
Endif
Print ($try+". pokusaj neuspesan: ...Skripta: Hemo.Net@lite")
inc( $try )
sleep( 5000 )
Print ("Ponovni pokusaj... "+$try+". put ...Skripta: Hemo.Net@lite")
endwhile
# Ako je doslo do nekakve nepredvidjene greske i nije uspesno povezivanje na provajdera, onda prekida skriptu
If (!RasIsConnected)
HAmNewsJobsClear
Quit
endif
Print ("Uspesno povezivanje!!! ...Skripta: Hemo.Net@lite")
# Potrebno je da je podesena sifra za POP server
HamFetchMail( "pop.hemo.net" )
HamSendMail( "smtp.hemo.net" )
# Odabir servera na koji se salje
HamNewsJobsPost( "news.hemo.net" )
# Skidanje poruka
hamnewsjobspull ("news.hemo.net")
# Pocetak izvrsavanja zadataka vezanih za news
HamNewsJobsStart
Print ("Cekam kraj svih kenekcija, pa prekidam vezu")
HamWaitIdle
# Snima nesnimljene podatke na disk
HamFlush
# Prekida vezu
HamRasHangup
# Ukljucivanje lokalnih servera
# News, POP3, SMTP
HamMessage ( 3, 0)
HamMessage ( 4, 0)
HamMessage ( 5, 0)
quit
Gotova skripta se može naći ovde, ili copy/paste u novi fajl sa nastavkom .HSC...
Jos jedna česta pojava je da treba proveravati više naloga na istom serveru...
Ovo se može postići jednostavnim redjanjem više POP servera u nizu naredbi u skripti: HamFetchMail ("POP.sever1.com", "", "korisnicko_ime", "lozinka", "lokalni_korisnik", "primenjeni_filter") HamFetchMail ("POP.sever1.com", "", "korisnicko_ime2", "lozinka2", "lokalni_korisnik2", "primenjeni_filter2") itd.
Ako je potrebno pozivati ove servere jednostavnije je da je napravi zasebna procedura, nazvana recimo "ProveriPostuNaSvimServerima()", koja ce biti smeštena u zaseban modul iz koga će se pozivati po potrebi... Tako ce sve šifre biti na jednom mestu i pojednostaviće se održavanje...
Primer: Napravimo modul, recimo "moje_skripte.hsm" koji sadrži sledeće:
############################################################### # Provera vise mail naloga, za jedan isti server # Kratak opis naredbe HamFetchMail: # HamFetchMail ( <server>, <port>, <korisnicko ime>, <lozinka>, <lokalni korisnik>, <filter> # <Lokalni korisnik> - odrediste za poruke, default Admin # <filter> - koji odeljak iz mailfilt.hst da primeni pri filtriranju ############################################################### Sub ProveriPostuNaSvimServerima() HamFetchMail( "pop.mail.yahoo.com", "", "anti1ic", "XXXXXXXX", "", "" ) HamFetchMail( "pop.mail.yahoo.com", "", "HTML_tutor_1", "xxxxxxxx", "", "" ) HamFetchMail( "pop.mail.yahoo.com", "", "antilic", "xxxxxxxxx", "", "" ) # Serveri koji imaju podesene lozinke u Hamsteru, za neki server mogu se navesti i ovako: HamFetchMail( "pop.hemo.net" ) HamFetchMail( "pop3.ptt.yu" ) endsub
Sada je potrebno "ukljuciti" modul u skriptu iz koje se poziva ova procedura, i onda je pozvati. U skripti bi to izgledalo ovako:
#!load moje_skripte.hsm # Deo skripte za pozivanje i povezivanje na provajdera . . . ProveriPostuNaSvimServerima() . . . # I nastavlja se sa proverom news-a, slanje poruka i prekidanjem konekcije, kada zavrsi skidanje poruka
Mislim da je to sasvim dovoljno za svakoga ko tek počinje da koristi Hamster... Ako želite da pogledate jos zanimljivih procedura, kliknite ovde!